mirror of
https://github.com/ggml-org/llama.cpp.git
synced 2025-11-14 11:07:10 +00:00
74b8fc17f9
* Add profiling * More detailed profiling * Rework command submission to avoid global locks * Update wait handling * try new method of waiting on futures * Add serializing of command submission in some cases * Add new pool for timestamp queries and clean up logging * Serialize command submission in CI and leave a TODO note * Update webgpu CI * Add myself as WebGPU codeowner * Deadlock avoidance * Leave WebGPU/Vulkan CI serialized * Fix divide by 0 * Fix logic in division by inflight_threads * Update CODEOWNERS and remove serialize submit option
63 lines
2.1 KiB
CMake
63 lines
2.1 KiB
CMake
cmake_minimum_required(VERSION 3.13)
|
|
|
|
find_package(Python3 REQUIRED)
|
|
|
|
# Shader locations
|
|
set(SHADER_DIR "${CMAKE_CURRENT_SOURCE_DIR}/wgsl-shaders")
|
|
set(SHADER_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/generated")
|
|
set(SHADER_HEADER "${SHADER_OUTPUT_DIR}/ggml-wgsl-shaders.hpp")
|
|
file(MAKE_DIRECTORY ${SHADER_OUTPUT_DIR})
|
|
|
|
message(STATUS "Shader output dir: ${SHADER_OUTPUT_DIR}")
|
|
|
|
# Find all WGSL files
|
|
file(GLOB WGSL_SHADER_FILES "${SHADER_DIR}/*.wgsl")
|
|
|
|
# Generate the header using a Python script
|
|
add_custom_command(
|
|
OUTPUT ${SHADER_HEADER}
|
|
COMMAND ${CMAKE_COMMAND} -E echo "Embedding WGSL shaders to ggml-wgsl-shaders.hpp"
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory ${SHADER_OUTPUT_DIR}
|
|
COMMAND ${CMAKE_COMMAND} -E env PYTHONIOENCODING=utf-8
|
|
${Python3_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgsl-shaders/embed_wgsl.py
|
|
--input_dir "${SHADER_DIR}"
|
|
--output_file "${SHADER_HEADER}"
|
|
DEPENDS ${WGSL_SHADER_FILES} ${CMAKE_CURRENT_SOURCE_DIR}/wgsl-shaders/embed_wgsl.py
|
|
VERBATIM
|
|
)
|
|
|
|
add_custom_target(generate_shaders DEPENDS ${SHADER_HEADER})
|
|
|
|
ggml_add_backend_library(ggml-webgpu
|
|
ggml-webgpu.cpp
|
|
${SHADER_HEADER}
|
|
../../include/ggml-webgpu.h
|
|
)
|
|
|
|
add_dependencies(ggml-webgpu generate_shaders)
|
|
|
|
if(EMSCRIPTEN)
|
|
set(EMDAWNWEBGPU_DIR "" CACHE PATH "Path to emdawnwebgpu_pkg")
|
|
|
|
target_compile_options(ggml-webgpu PRIVATE "--use-port=${EMDAWNWEBGPU_DIR}/emdawnwebgpu.port.py")
|
|
target_link_options(ggml-webgpu PRIVATE "--use-port=${EMDAWNWEBGPU_DIR}/emdawnwebgpu.port.py")
|
|
else()
|
|
find_package(Dawn REQUIRED)
|
|
set(DawnWebGPU_TARGET dawn::webgpu_dawn)
|
|
endif()
|
|
|
|
if (GGML_WEBGPU_DEBUG)
|
|
target_compile_definitions(ggml-webgpu PRIVATE GGML_WEBGPU_DEBUG=1)
|
|
endif()
|
|
|
|
if (GGML_WEBGPU_CPU_PROFILE)
|
|
target_compile_definitions(ggml-webgpu PRIVATE GGML_WEBGPU_CPU_PROFILE=1)
|
|
endif()
|
|
|
|
if (GGML_WEBGPU_GPU_PROFILE)
|
|
target_compile_definitions(ggml-webgpu PRIVATE GGML_WEBGPU_GPU_PROFILE=1)
|
|
endif()
|
|
|
|
target_include_directories(ggml-webgpu PRIVATE ${SHADER_OUTPUT_DIR})
|
|
target_link_libraries(ggml-webgpu PRIVATE ${DawnWebGPU_TARGET})
|